#+TITLE:       sdp output xmls
#+AUTHOR:      Ralph Amissah
#+EMAIL:       [[mailto:ralph.amissah@gmail.com][ralph.amissah@gmail.com]]
#+DESCRIPTION: documents - structuring, publishing in multiple formats & search
#+KEYWORDS
#+LANGUAGE:    en
#+STARTUP:     indent content
#+OPTIONS:     H:3 num:nil toc:t \n:nil @:t ::t |:t ^:nil _:nil -:t f:t *:t <:t
#+OPTIONS:     TeX:t LaTeX:t skip:nil d:nil todo:t pri:nil tags:not-in-toc
#+OPTIONS:     author:nil email:nil creator:nil timestamp:nil
#+PROPERTY:    header-args :padline no :exports code :noweb yes
#+EXPORT_SELECT_TAGS:  export
#+EXPORT_EXCLUDE_TAGS: noexport
#+FILETAGS:            :sdp:rel:output:xmls:
#+TAGS: assert(a) class(c) debug(d) mixin(m) sdp(s) tangle(T) template(t) WEB(W) noexport(n)

- [[./sdp.org][sdp]]  [[./][org/]]
- [[./output_hub.org][output_hub]]

* xml offspring (xhtml html epub)                    :module:sdp:output_xmls:
** format xhtml objects                                             :format:
*** 0. module template

#+BEGIN_SRC d :tangle ../src/sdp/output/xmls.d
module sdp.output.xmls;
template outputXHTMLs() {
  <<output_imports>>
  mixin SiSUoutputRgxInit;
  struct outputXHTMLs {
    static auto rgx = Rgx();
    <<xhtml_format_objects>>
    <<xhtml_format_objects_code>>
  }
}
#+END_SRC

*** output imports

#+name: output_imports
#+BEGIN_SRC d
import sdp.output;
import
  std.digest.sha,
  std.file,
  std.outbuffer,
  std.zip,
  std.conv : to;
import
  sdp.output.create_zip_file,
  sdp.output.xmls,
  sdp.output.xmls_css;
#+END_SRC

*** misc
**** div delimiter

#+name: xhtml_format_objects
#+BEGIN_SRC d
string div_delimit(
  string                     part,
  return ref string          previous_part
){
  string delimit = "";
  string delimit_ = "";
  if (part != previous_part) {
    switch (part) {
    case "head":
      delimit_ ~= "\n<div class=\"doc_title\">\n" ;
      break;
    case "toc_seg":
      delimit_ ~= "\n<div class=\"doc_toc\">\n" ;
      break;
    case "toc_scroll":
      delimit_ ~= "\n<div class=\"doc_toc\">\n" ;
      break;
    case "bookindex_seg":
      delimit_ ~= "\n<div class=\"doc_bookindex\">\n" ;
      break;
    case "bookindex_scroll":
      delimit_ ~= "\n<div class=\"doc_bookindex\">\n" ;
      break;
    default:
      delimit_ ~= "\n<div class=\"doc_" ~ part ~ "\">\n" ;
      break;
    }
    if (previous_part.length > 0) {
      delimit ~= "\n</div>";
    }
    previous_part = part;
    delimit ~=  delimit_;
  }
  // you also need to close the last div, introduce a footer?
  return delimit;
}
#+END_SRC
**** special characters

#+name: xhtml_format_objects
#+BEGIN_SRC d
string special_characters(O)(
  auto return ref const O    obj,
  string                     _txt
){
  _txt = (_txt)
    .replaceAll(rgx.xhtml_ampersand,    "&#38;")
    .replaceAll(rgx.xhtml_quotation,    "&#34;")
    .replaceAll(rgx.xhtml_less_than,    "&#60;")
    .replaceAll(rgx.xhtml_greater_than, "&#62;")
    .replaceAll(rgx.nbsp_char,          " ");
  if (!(obj.metainfo.is_a == "code")) {
    _txt = (_txt)
      .replaceAll(rgx.xhtml_line_break,   "<br />");
  }
  return _txt;
}
#+END_SRC

**** special characters text

#+name: xhtml_format_objects
#+BEGIN_SRC d
string special_characters_text(string _txt){
  _txt = (_txt)
    .replaceAll(rgx.xhtml_ampersand,    "&#38;")
    .replaceAll(rgx.xhtml_quotation,    "&#34;")
    .replaceAll(rgx.xhtml_less_than,    "&#60;")
    .replaceAll(rgx.xhtml_greater_than, "&#62;")
    .replaceAll(rgx.nbsp_char,          " ");
  return _txt;
}
#+END_SRC

**** font_face

#+name: xhtml_format_objects
#+BEGIN_SRC d
string font_face(string _txt){
  _txt = (_txt)
    .replaceAll(rgx.inline_emphasis,    ("<em>$1</em>"))
    .replaceAll(rgx.inline_bold,        ("<b>$1</b>"))
    .replaceAll(rgx.inline_underscore,  ("<u>$1</u>"))
    .replaceAll(rgx.inline_italics,     ("<i>$1</i>"))
    .replaceAll(rgx.inline_superscript, ("<sup>$1</sup>"))
    .replaceAll(rgx.inline_subscript,   ("<sub>$1</sub>"))
    .replaceAll(rgx.inline_strike,      ("<del>$1</del>"))
    .replaceAll(rgx.inline_insert,      ("<ins>$1</ins>"))
    .replaceAll(rgx.inline_mono,        ("<tt>$1</tt>"))
    .replaceAll(rgx.inline_cite,        ("<cite>$1</cite>"));
  return _txt;
}
#+END_SRC

**** anchor tags

#+name: xhtml_format_objects
#+BEGIN_SRC d
string _xhtml_anchor_tags(const(string[]) anchor_tags) {
  string tags="";
  if (anchor_tags.length > 0) {
    foreach (tag; anchor_tags) {
      if (!(tag.empty)) {
        tags ~= "<a name=\"" ~ tag ~ "\"></a>";
      }
    }
  }
  return tags;
}
#+END_SRC

**** doc head & tails
***** metadata

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto header_metadata(M)(
  M  doc_matters,
) {
  string _title="Title";
  string _author="Author";
  string _publisher="Publisher";
  string _date="Date";
  string _date_created="Date";
  string _date_issued="Date";
  string _date_available="Date";
  string _date_valid="Date";
  string _date_modified="Date";
  string _language="en";
  string _rights="Copyright: Copyright (C) year holder";
  string _generator="sdp [SiSU 7.1.8 of 2016w08/5 (2016-02-26)] (n*x and D)";
  string _generator_home="http://www.sisudoc.org";
  string o;
  o = format(q"¶<!-- SiSU header metadata -->
<meta http-equiv="Content-Type" content="text/html;charset=utf-8" />
<meta name="dc.title" content="%s" />
<meta name="dc.author" content="%s" />
<meta name="dc.publisher" content="%s" />
<meta name="dc.date" content="%s" />
<meta name="dc.date.created" content="%s" />
<meta name="dc.date.issued" content="%syear" />
<meta name="dc.date.available" content="%syear" />
<meta name="dc.date.valid" content="%syear" />
<meta name="dc.date.modified" content="%syear" />
<meta name="dc.language" content="%s" />
<meta name="dc.rights" content="%s" />
<meta name="generator" content="%s" />
<link rel="generator" href="%s" />
<!-- SiSU header metadata -->¶",
  _title,
  _author,
  _publisher,
  _date,
  _date_created,
  _date_issued,
  _date_available,
  _date_valid,
  _date_modified,
  _language,
  _rights,
  _generator,
  _generator_home,
  );
  return o;
}
#+END_SRC

***** site info button

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto site_info_button(M)(
  M  doc_matters,
) {
  string _locations;
  if (doc_matters.conf_make_meta.make.home_button_text.length > 0) {
    _locations = (doc_matters.conf_make_meta.make.home_button_text)
      .replaceAll(
        rgx.inline_link,
        ("<p class=\"tiny_left\"><a href=\"$2\">$1</a></p>"))
      .replaceAll(
        rgx.br_line, "")
      .replaceAll(
        rgx.br_nl, "");
  } else {
     _locations = "<p class=\"tiny_left\"><a href=\"http://www.sisudoc.org\">SiSU</a></p>\n<p class=\"tiny_left\"><a href=\"http://www.sisudoc.org\">www.sisudoc.org</a></p>\n<p class=\"tiny_left\"><a href=\"http://git.sisudoc.org/gitweb/\">sources / git</a></p>";
  }
  string o;
  o = format(q"¶<div class="flex-menu-option">
      %s
    </div>¶",
  _locations,
  );
  return o;
}
#+END_SRC

***** search form

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_search_form(M)(
  M  doc_matters,
) {
  string _action="http://www.sisudoc.org/cgi-bin/search.cgi";
  string _db="SiSU.7a.manual";
  string o;
  o = format(q"¶<div class="flex-menu-option">
      <a name="search"></a>
      <form method="get" action="%s" target="_top">
      <font size="2">
      <input type="text" name="s1" size="24" maxlength="255" />
      <input type="hidden" name="db" value="%s" />
      <input type="hidden" name="ltd" value="1000" />
      <input type="hidden" name="off" value="0" />
      <input type="hidden" name="doc" value="live-manual" /><br />
      <input type="submit" name="search" value="search doc" />
      <input type="submit" name="search" value="search db" />
      </font></form>
    </div>¶",
  _action,
  _db,
  );
  return o;
}
#+END_SRC

***** html head & head banner

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto html_head(M)(
  M  doc_matters,
  string type,
) {
  string o;
  o = format(q"¶<!DOCTYPE html>
<html>
<head>
  <meta charset="utf-8" />
  <title>
    %s%s
  </title>
  <!-- metadata -->
  %s
  <!-- metadata -->
  <link rel="generator" href="http://www.sisudoc.org/" />
  <link rel="shortcut icon" href="%s" />
  <link href="%s" rel="stylesheet" />
</head>
<body lang="%s">
<a name="top" id="top"></a>
<div class='delimit headband'>
  <div class="flex-menu-bar">
    %s
    <div class="flex-menu-option">
      <a href="../../manifest/sisu.en.html" target="_top">
        <font face="verdana, arial, georgia, tahoma, sans-serif, helvetica, times, roman" size="2">
          [&nbsp;document&nbsp;manifest&nbsp;]
        </font>
      </a>
    </div>
    %s%s¶",
    doc_matters.conf_make_meta.meta.title_full,
    (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
      : ", " ~ doc_matters.conf_make_meta.meta.creator_author,
    header_metadata(doc_matters),
    ((type == "seg") ? "../../../" : "../../") ~ "image/rb7.ico",
    ((type == "seg")
      ? "../../../css/html_seg.css"
      : "../../css/html_scroll.css"),
    doc_matters.src.language,
    site_info_button(doc_matters),
    inline_search_form(doc_matters),
    ((type == "seg") ? "" : "\n</div>"),
  );
  return o;
}
#+END_SRC

***** epub seg head

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto epub3_seg_head(M)(
  M  doc_matters,
) {
  string html_base = format(q"¶<!DOCTYPE html>
<html>¶",
);
  string html_simple = format(q"¶<!DOCTYPE html>
<html
  xmlns="http://www.w3.org/1999/xhtml"
  xmlns:epub="http://www.idpf.org/2007/ops"
  lang="%s" xml:lang="%s">¶",
    doc_matters.src.language,
    doc_matters.src.language,
  );
  string html_strict = format(q"¶<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN"
     "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml"
  xmlns:epub="http://www.idpf.org/2007/ops"
  lang="%s" xml:lang="%s">¶",
    doc_matters.src.language,
    doc_matters.src.language,
  );
  string o;
  o = format(q"¶%s
<head>
  <title>
    %s%s
  </title>
  <meta http-equiv="Content-Type" content="text/html;charset=utf-8" />
  <meta name="dc.title" content="%s" />
  <meta name="dc.author" content="%s" />
  <meta name="dc.publisher" content="SiSU http://www.jus.uio.no/sisu (this copy)" />
  <meta name="dc.date" content="year" />
  <meta name="dc.date.created" content="year" />
  <meta name="dc.date.issued" content="year" />
  <meta name="dc.date.available" content="year" />
  <meta name="dc.date.valid" content="year" />
  <meta name="dc.date.modified" content="year" />
  <meta name="dc.language" content="US" />
  <meta name="dc.rights" content="Copyright: Copyright (C) year holder" />
  <meta name="generator" content="sdp [SiSU 7.1.8 of 2016w08/5 (2016-02-26)] (n*x and D)" />
  <link rel="generator" href="http://www.sisudoc.org/" />
  <link rel="shortcut icon" href="../_sisu/image/rb7.ico" />
  <link rel="stylesheet" href="css/epub.css" type="text/css" id="main-css" />
</head>
<body lang="%s">
<a name="top" id="top"></a>¶",
    html_simple,
    doc_matters.conf_make_meta.meta.title_full,
    (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
      : ", " ~ doc_matters.conf_make_meta.meta.creator_author,
    doc_matters.conf_make_meta.meta.title_full,
    (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
      : ", " ~ doc_matters.conf_make_meta.meta.creator_author,
    doc_matters.src.language,
  );
  return o;
}
#+END_SRC

***** xhtml tail

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto tail() {
  string o;
  o = format(q"¶  </div>
  <a name="bottom" id="bottom"></a>
  <a name="end" id="end"></a>
</body>
</html>¶");
  return o;
}
#+END_SRC

*** inline markup
**** images

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_images(O)(
  auto return ref const O obj,
  string                  _txt,
  string                  _suffix    = ".html",
  string                  _xml_type = "seg",
) {
  string _img_pth;
  if (_xml_type == "epub") {
    _img_pth = "image/";
  } else if (_xml_type == "scroll") {
    _img_pth = "../../image/";
  } else if (_xml_type == "seg") {
    _img_pth = "../../../image/";
  }
  if (_txt.match(rgx.inline_image)) {
    _txt = _txt.replaceAll( // TODO bug where image dimensions (w or h) not given & consequently set to 0; should not be used (calculate earlier, abstraction)
        rgx.inline_image,
        ("$1<img src=\""
          ~ _img_pth
          ~ "$3\" width=\"$4\" height=\"$5\" naturalsizeflag=\"0\" align=\"bottom\" border=\"0\" /> $6"));
  }
  return _txt;
}
#+END_SRC

**** links

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_links(O)(
  auto return ref const O obj,
  string                  _txt,
  string                  _suffix    = ".html",
  string                  _xml_type = "seg",
) {
  if (obj.has.inline_links) {
    if ((_txt.match(rgx.mark_internal_site_lnk))
    && (_xml_type == "scroll")) { // conditions reversed to avoid: gdc compiled program run segfault
      _txt = (_txt).replaceAll(
        rgx.inline_seg_link,
        "$1");
    }
    _txt = (_txt)
      .replaceAll(
        rgx.inline_link_fn_suffix,
        ("$1" ~ _suffix))
      .replaceAll(
        rgx.inline_link,
        ("<a href=\"$2\">$1</a>"))
      .replaceAll(
        rgx.mark_internal_site_lnk,
        "");
  }
  debug(markup_links) {
    if (_txt.match(rgx.inline_link)) {
      writeln(__LINE__,
        " (missed) markup link identified (",
        obj.has.inline_links,
        "): ", obj.metainfo.is_a, ": ",
        obj.text
      );
    }
  }
  debug(markup) {
    if (_txt.match(rgx.inline_link)) {
      writeln(__LINE__,
        " (missed) markup link identified (",
        obj.has.inline_links,
        "): ", obj.metainfo.is_a, ": ",
        obj.text
      );
    }
  }
  return _txt;
}
#+END_SRC

**** notes scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_notes_scroll(O)(
  auto return ref const O   obj,
  string                    _txt,
) {
  if (obj.has.inline_notes_reg) {
    _txt = font_face(_txt);
    _txt = (_txt).replaceAll(
      rgx.inline_notes_delimiter_al_regular_number_note,
      ("<a href=\"#note_$1\"><note id=\"noteref_$1\">&#160;<sup>$1</sup> </note></a>")
    );
  }
  debug(markup_endnotes) {
    if (_txt.match(rgx.inline_notes_delimiter_al_regular_number_note)) {
      writeln(__LINE__, " (missed) markup endnote: ", obj.metainfo.is_a, ": ", obj.text);
    }
  }
  debug(markup) {
    if (_txt.match(rgx.inline_notes_delimiter_al_regular_number_note)) {
      writeln(__LINE__, " (missed) markup endnote: ", obj.metainfo.is_a, ": ", obj.text);
    }
  }
  return _txt;
}
#+END_SRC

**** notes seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_notes_seg(O)(
  auto return ref const O     obj,
  string                      _txt,
) {
  string[] _endnotes;
  if (obj.has.inline_notes_reg) {
    _txt = font_face(_txt);
    /+ need markup for text, and separated footnote +/
    foreach(m; _txt.matchAll(rgx.inline_notes_delimiter_al_regular_number_note)) {
      _endnotes ~= format(
        "%s%s%s%s\n  %s%s%s%s%s\n  %s\n%s",
        "<p class=\"endnote\">",
        "<a href=\"#noteref_",
        m.captures[1],
        "\">",
        "<note id=\"note_",
        m.captures[1],
        "\">&#160;<sup>",
        m.captures[1],
        ".</sup></note></a>",
        m.captures[2],
        "</p>"
      );
    }
    _txt = (_txt).replaceAll(
      rgx.inline_notes_delimiter_al_regular_number_note,
      ("<a href=\"#note_$1\"><note id=\"noteref_$1\">&#160;<sup>$1</sup> </note></a>")
    );
  } else if (_txt.match(rgx.inline_notes_delimiter_al_regular_number_note)) {
    debug(markup) {
      writeln(__LINE__, " endnote: ", obj.metainfo.is_a, ": ", obj.text);
    }
  }
  auto t = tuple(
    _txt,
    _endnotes,
  );
  return t;
}
#+END_SRC

**** inline markup scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_markup_scroll(O)(
  auto return ref const O  obj,
  string                   _txt,
  string                   _suffix = ".html",
) {
  _txt = inline_images(obj, _txt, _suffix, "scroll");
  _txt = inline_links(obj, _txt, _suffix, "scroll");
  _txt = inline_notes_scroll(obj, _txt);
  return _txt;
}
#+END_SRC

**** inline markup seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto inline_markup_seg(O)(
  auto return ref const O  obj,
  string                   _txt,
  string                   _suffix = ".html",
  string                   _xml_type = "seg",
) {
  _txt = inline_images(obj, _txt, _suffix, _xml_type);
  _txt = inline_links(obj, _txt, _suffix, _xml_type);
  auto t = inline_notes_seg(obj, _txt);
  return t;
}
#+END_SRC

*** toc
**** subtoc

#+name: xhtml_format_objects
#+BEGIN_SRC d
string lev4_heading_subtoc(O)(
  auto return ref const O    obj,
) {
  char[] lev4_subtoc;
  lev4_subtoc ~= "  <div class=\"nav\">\n";
  foreach (subtoc; obj.tags.lev4_subtoc) {
    if (auto m = subtoc.match(rgx.inline_link_subtoc)) {
      auto indent = m.captures[1].to!string;
      auto text = m.captures[2].to!string;
      text = font_face(text);
      auto link = m.captures[3].to!string;
      lev4_subtoc ~= subtoc.replaceFirst(rgx.inline_link_subtoc,
        format(q"¶    <p class="minitoc" indent="h%si%s">
      <a href="%s">%s</a>
    </p>
¶",
          indent,
          indent,
          link,
          text,
      ));
    }
  }
  lev4_subtoc ~= "  </div>\n";
  return lev4_subtoc.to!string;
}
#+END_SRC

**** navigation pre next svg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto nav_pre_next_svg(O)(
  auto return ref const O    obj,
) {
  string prev, next, toc;
  if (obj.tags.segment_anchor_tag == "toc") {
    toc = "";
    prev = "";
  } else {
    toc = format(q"¶<a href="toc.html" target="_top">
          <div class="toc-button menu">
            <svg viewbox="0 0 100 100">
              <path d="M4,10h24c1.104,0,2-0.896,2-2s-0.896-2-2-2H4C2.896,6,2,6.896,2,8S2.896,10,4,10z M28,14H4c-1.104,0-2,0.896-2,2  s0.896,2,2,2h24c1.104,0,2-0.896,2-2S29.104,14,28,14z M28,22H4c-1.104,0-2,0.896-2,2s0.896,2,2,2h24c1.104,0,2-0.896,2-2  S29.104,22,28,22z"/>
            </svg>
          </div>
        </a>¶",
    );
  }
  if (obj.tags.segname_prev == "") {
    prev = "";
  } else {
    prev = format(q"¶<a href="%s.html" target="_top">
          <div class="prev-next-button previous">
            <svg viewbox="0 0 100 100">
              <path class="arrow" d="M 50,0 L 60,10 L 20,50 L 60,90 L 50,100 L 0,50 Z" transform=" translate(15,0)">
            </svg>
          </div>
        </a>¶",
      obj.tags.segname_prev,
    );
  }
  if (obj.tags.segname_next == "") {
    next = "";
  } else {
    next = format(q"¶<a href="%s.html" target="_top">
          <div class="prev-next-button next">
            <svg viewbox="0 0 100 100">
              <path class="arrow" d="M 50,0 L 60,10 L 20,50 L 60,90 L 50,100 L 0,50 Z "transform="translate(85,100) rotate(180) ">
            </svg>
          </div>
        </a>¶",
      obj.tags.segname_next,
    );
  }
  string _toc_pre_next = format(q"¶        <div class="flex-menu-option">
      <div class="nav-bar">
        %s
        %s
        %s
      </div>
    </div>
  </div>
</div>¶",
    toc,
    prev,
    next,
  );
  string _pre_next = format(q"¶        <div class="flex-menu-option">
      <div class="nav-bar">
        %s
        %s
      </div>
    </div>
  </div>
</div>¶",
    prev,
    next,
  );
  struct bar {
    string toc_pre_next() {
      return _toc_pre_next;
    }
    string pre_next() {
      return _pre_next;
    }
  }
  return bar();
}
#+END_SRC

*** heading
**** heading

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto heading(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _xml_type = "html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  string _horizontal_rule = "<hr />";
  if ((_xml_type != "html")
  || (obj.metainfo.heading_lev_markup == 0 || obj.metainfo.heading_lev_markup > 4)) {
    _horizontal_rule = "";
  }
  _txt = font_face(_txt);
  string o;
  if (obj.metainfo.object_number.empty) {
    o = format(q"¶%s
  <div class="substance">
    <h%s class="%s">%s
      %s
    </h%s>
  </div>¶",
      _horizontal_rule,
      obj.metainfo.heading_lev_markup,
      obj.metainfo.is_a,
      tags,
      _txt,
      obj.metainfo.heading_lev_markup,
    );
  } else {
    o = format(q"¶%s
  <div class="substance">
    <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
    <h%s class="%s" id="%s"><a name="%s"></a>%s
      %s
    </h%s>
  </div>¶",
    _horizontal_rule,
    obj.metainfo.object_number,
    obj.metainfo.object_number,
    obj.metainfo.heading_lev_markup,
    obj.metainfo.is_a,
    obj.metainfo.object_number,
    obj.metainfo.object_number,
    tags,
    _txt,
    obj.metainfo.heading_lev_markup,
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto heading_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = heading(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto heading_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0];
  string[] _endnotes = t[1];
  string o = heading(obj, _txt, _xml_type);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** para
**** para

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto para(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = font_face(_txt);
  string o;
  _txt = (obj.attrib.bullet) ? ("●&#160;&#160;" ~ _txt) : _txt;
  if (obj.metainfo.object_number.empty) {
    o = format(q"¶  <div class="substance">
  <p class="%s" indent="h%si%s">%s
    %s
  </p>
</div>¶",
      obj.metainfo.is_a,
      obj.attrib.indent_hang,
      obj.attrib.indent_base,
      tags,
      _txt
    );
  } else {
    o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" indent="h%si%s" id="%s">%s
    %s
  </p>
</div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.attrib.indent_hang,
      obj.attrib.indent_base,
      obj.metainfo.object_number,
      tags,
      _txt
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto para_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = para(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto para_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0].to!string;
  string[] _endnotes = t[1];
  string o = para(obj, _txt);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** quote
**** quote

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto quote(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  _txt = font_face(_txt);
  string o;
  if (obj.metainfo.object_number.empty) {
    o = format(q"¶  <div class="substance">
  <p class="%s">
    %s
  </p>
</div>¶",
      obj.metainfo.is_a,
      _txt
    );
  } else {
    o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" id="%s">
    %s
  </p>
</div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.metainfo.object_number,
      _txt
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto quote_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = quote(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto quote_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0].to!string;
  string[] _endnotes = t[1];
  string o = quote(obj, _txt);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** group
**** group

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto group(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  _txt = font_face(_txt);
  string o;
  if (obj.metainfo.object_number.empty) {
    o = format(q"¶  <div class="substance">
  <p class="%s">
    %s
  </p>
</div>¶",
      obj.metainfo.is_a,
      _txt
    );
  } else {
    o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" id="%s">
    %s
  </p>
</div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.metainfo.object_number,
      _txt
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto group_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = group(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto group_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0].to!string;
  string[] _endnotes = t[1];
  string o = group(obj, _txt);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** block
**** block

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto block(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  _txt = font_face(_txt);
  string o;
  if (obj.metainfo.object_number.empty) {
    o = format(q"¶  <div class="substance">
  <p class="%s">%s</p>
</div>¶",
      obj.metainfo.is_a,
      _txt.stripRight
    );
  } else {
    o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" id="%s">%s</p>
</div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.metainfo.object_number,
      _txt.stripRight
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto block_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = block(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto block_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0].to!string;
  string[] _endnotes = t[1];
  string o = block(obj, _txt);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** poem verse
**** verse

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto verse(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  _txt = font_face(_txt);
  string o;
  if (obj.metainfo.object_number.empty) {
      o = format(q"¶  <div class="substance">
        <p class="%s">%s</p>
    </div>¶",
      obj.metainfo.is_a,
      _txt
    );
  } else {
    o = format(q"¶  <div class="substance">
      <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
      <p class="%s" id="%s">%s</p>
    </div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.metainfo.object_number,
      _txt
    );
  }
  return o;
}
#+END_SRC

**** scroll

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto verse_scroll(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = inline_markup_scroll(obj, _txt, _suffix);
  string o = verse(obj, _txt);
  return o;
}
#+END_SRC

**** seg

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto verse_seg(O)(
  auto return ref const O    obj,
  string                     _txt,
  string                     _suffix = ".html",
  string                     _xml_type = "html",
) {
  auto t = inline_markup_seg(obj, _txt, _suffix, _xml_type);
  _txt = t[0].to!string;
  string[] _endnotes = t[1];
  string o = verse(obj, _txt);
  auto u = tuple(
    o,
    _endnotes,
  );
  return u;
}
#+END_SRC

*** code

#+name: xhtml_format_objects_code
#+BEGIN_SRC d
auto code(O)(
  auto return ref const O  obj,
  string                   _txt,
) {
  string o;
  if (obj.metainfo.object_number.empty) {
      o = format(q"¶  <div class="substance">
    <p class="%s">%s</p>
</div>¶",
      obj.metainfo.is_a,
      _txt
    );
  } else {
    o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" id="%s">%s</p>
</div>¶",
      obj.metainfo.object_number,
      obj.metainfo.object_number,
      obj.metainfo.is_a,
      obj.metainfo.object_number,
      _txt
    );
  }
  return o;
}
#+END_SRC

*** table
**** TODO tablarize

align="left|right|center"
<td align="right">$100</td>

"style=\"text-align:right\""
"style=\"text-align:left\""

"style=\"text-align:"  ~ "right\""

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto tablarize(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  string[] _table_rows = (_txt).split(rgx.table_delimiter_row);
  string[] _table_cols;
  string _table;
  string _tablenote;
  foreach(row_idx, row; _table_rows) {
    _table_cols = row.split(rgx.table_delimiter_col);
      _table ~= "<tr>";
      foreach(col_idx, cell; _table_cols) {
        if ((_table_cols.length == 1)
        && (_table_rows.length <= row_idx+2)) {
          _tablenote ~= cell;
        } else {
          string _col_is = (row_idx == 0 && obj.table.heading) ? "th" : "td";
          string _align = ("style=\"text-align:"
          ~ ((obj.table.column_aligns[col_idx] == "l")
          ? "left\"" : "right\""));
          _table ~= "<" ~ _col_is ~ " width=\"" ~ obj.table.column_widths[col_idx].to!string ~ "%\" " ~ _align ~ ">";
          _table ~= cell;
          _table ~= "</" ~ _col_is ~ ">";
        }
      }
      _table ~= "</tr>";
    }
  auto t = tuple(
    _table,
    _tablenote,
  );
  return t;
}
#+END_SRC

**** table

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto table(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  auto tags = _xhtml_anchor_tags(obj.tags.anchor_tags);
  _txt = font_face(_txt);
  auto t = tablarize(obj, _txt);
  _txt = t[0];
  string _note = t[1];
  string o;
  o = format(q"¶  <div class="substance">
  <label class="ocn"><a href="#%s" class="lnkocn">%s</a></label>
  <p class="%s" id="%s">%s
    <table summary="normal text css" width="95%%" border="0" bgcolor="white" cellpadding="2" align="center">
      %s
    </table>
    %s
  </p>
</div>¶",
    obj.metainfo.object_number,
    obj.metainfo.object_number,
    obj.metainfo.is_a,
    obj.metainfo.object_number,
    tags,
    _txt,
    _note
  );
  return o;
}
#+END_SRC

*** endnote

#+name: xhtml_format_objects
#+BEGIN_SRC d
auto endnote(O)(
  auto return ref const O    obj,
  string                     _txt,
) {
  string o;
  o = format(q"¶    <p class="%s" indent="h%si%s">
  %s
</p>¶",
    obj.metainfo.is_a,
    obj.attrib.indent_hang,
    obj.attrib.indent_base,
    _txt
  );
  return o;
}
#+END_SRC

* _html_ [#A]                                          :module:sdp:output_html:
** module template

#+BEGIN_SRC d :tangle ../src/sdp/output/html.d
module sdp.output.html;
template outputHTML() {
  <<output_imports>>
  mixin outputXHTMLs;
  <<output_html_scroll>>
  <<output_html_seg>>
  <<output_html_css>>
  <<copy_html_images>>
}
#+END_SRC

** scroll                                                           :scroll:
*** ↻ loop & switch (sections & objects) format html output

#+name: output_html_scroll
#+BEGIN_SRC d
void scroll(D,I)(
  auto return ref const D    doc_abstraction,
  auto return ref I          doc_matters,
) {
  mixin SiSUoutputRgxInit;
  auto xhtml_format = outputXHTMLs();
  auto rgx = Rgx();
  string[] doc_html;
  string[] doc;
  string suffix = ".html";
  string previous_part = "";
  string delimit = "";
  foreach (part; doc_matters.xml.keys_seq.scroll) {
    foreach (obj; doc_abstraction[part]) {
      delimit = xhtml_format.div_delimit(part, previous_part);
      string _txt = xhtml_format.special_characters(obj, obj.text);
      switch (obj.metainfo.is_of_part) {
      case "frontmatter":              assert(part == "head" || "toc_scroll");
        switch (obj.metainfo.is_of_type) {
        case "para":
          switch (obj.metainfo.is_a) {
          case "heading":
            doc_html ~= delimit ~ xhtml_format.heading_scroll(obj, _txt, suffix);
            break;
          case "toc":
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
            }
            break;
          }
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
          }
          break;
        }
        break;
      case "body":                     assert(part == "body" || "head"); // surprise
        switch (obj.metainfo.is_of_type) {
        case "para":
          switch (obj.metainfo.is_a) {
          case "heading":
            doc_html ~= delimit ~ xhtml_format.heading_scroll(obj, _txt, suffix);
            break;
          case "para":
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
            }
            break;
          }
          break;
        case "block":
          switch (obj.metainfo.is_a) {
          case "quote":
            doc_html ~= xhtml_format.quote_scroll(obj, _txt);
            break;
          case "group":
            doc_html ~= xhtml_format.group_scroll(obj, _txt);
            break;
          case "block":
            doc_html ~= xhtml_format.block_scroll(obj, _txt);
            break;
          case "poem":
            break;
          case "verse":
            doc_html ~= xhtml_format.verse_scroll(obj, _txt, suffix);
            break;
          case "code":
            doc_html ~= xhtml_format.code(obj, _txt);
            break;
          case "table":
            doc_html ~= xhtml_format.table(obj, _txt);
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
            }
            break;
          }
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
          }
          break;
        }
        break;
      case "backmatter":
        assert(part == "endnotes" || "glossary" || "bibliography" || "bookindex_scroll" || "blurb" || "tail");
        switch (obj.metainfo.is_of_type) {
        case "para":
          switch (obj.metainfo.is_a) {
          case "heading":
            doc_html ~= delimit ~ xhtml_format.heading_scroll(obj, _txt, suffix);
            break;
          case "endnote":              assert(part == "endnotes");
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          case "glossary":             assert(part == "glossary");
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          case "bibliography":         assert(part == "bibliography");
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          case "bookindex":            assert(part == "bookindex_scroll");
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          case "blurb":                assert(part == "blurb");
            doc_html ~= xhtml_format.para_scroll(obj, _txt, suffix);
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
            }
            break;
          }
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
          }
          break;
        }
        break;
      case "comment":
        break;
      default:
        if ((doc_matters.opt.action.debug_do)) {
          writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_part);
          writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
          writeln(__FILE__, ":", __LINE__, ": ", obj.text);
        }
        break;
      }
    }
  }
  doc = xhtml_format.html_head(doc_matters, "scroll") ~ doc_html ~ xhtml_format.tail;
  scroll_write_output(doc_matters, doc);
}
#+END_SRC

*** write output file

#+name: output_html_scroll
#+BEGIN_SRC d
void scroll_write_output(M,C)(
  M doc_matters,
  C doc,
) {
  debug(asserts) {
    static assert(is(typeof(doc)    == string[]));
  }
  auto pth_html = SiSUpathsHTML!()(doc_matters.output_path, doc_matters.src.language);
  try {
    if (!exists(pth_html.base)) {
      pth_html.base.mkdirRecurse;
    }
    auto f = File(pth_html.fn_scroll(doc_matters.src.filename), "w");
    foreach (o; doc) {
      f.writeln(o);
    }
  }
  catch (ErrnoException ex) {
    // Handle error
  }
  writeln(" ", pth_html.fn_scroll(doc_matters.src.filename));
}
#+END_SRC

** seg                                                                 :seg:
*** ↻ loop & switch (sections & objects) format html output

#+name: output_html_seg
#+BEGIN_SRC d
void seg(D,M)(
  auto return ref const D    doc_abstraction,
  auto ref              M    doc_matters,
) {
  mixin SiSUoutputRgxInit;
  auto rgx = Rgx();
  auto xhtml_format = outputXHTMLs();
  string[][string] doc_html;
  string[][string] doc_html_endnotes;
  string[] doc;
  string segment_filename;
  string[] top_level_headings = ["","","",""];
  string previous_seg_filename = "";
  string suffix = ".html";
  string previous_part = "";
  string delimit = "";
  foreach (part; doc_matters.xml.keys_seq.seg) {
    foreach (obj; doc_abstraction[part]) {
      delimit = xhtml_format.div_delimit(part, previous_part);
      string _txt = xhtml_format.special_characters(obj, obj.text);
      if (obj.metainfo.is_a == "heading") {
        assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
        switch (obj.metainfo.heading_lev_markup) {
        case 0: .. case 3:
          /+ fill buffer, and replace with new levels from 1 to 3 +/
          switch (obj.metainfo.heading_lev_markup) {
          case 0:
            top_level_headings[0] = "";
            top_level_headings[1] = "";
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 1:
            top_level_headings[1] = "";
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 2:
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 3:
            top_level_headings[3] = "";
            goto default;
          default:
            auto t = xhtml_format.heading_seg(obj, _txt, suffix, "seg");
            top_level_headings[obj.metainfo.heading_lev_markup] = t[0];
            break;
          }
          break;
        case 4:
          segment_filename = obj.tags.segment_anchor_tag;
          doc_html[segment_filename] ~= xhtml_format.html_head(doc_matters, "seg");
          auto navigation_bar = xhtml_format.nav_pre_next_svg(obj);
          doc_html[segment_filename] ~= navigation_bar.toc_pre_next; // navigation bar
          previous_seg_filename = segment_filename;
          foreach (top_level_heading; top_level_headings) {
            // writeln(top_level_heading);
            doc_html[segment_filename] ~= top_level_heading;
          }
          auto t = xhtml_format.heading_seg(obj, _txt, suffix, "seg");
          doc_html[segment_filename] ~= t[0].to!string;
          doc_html[segment_filename] ~= xhtml_format.lev4_heading_subtoc(obj);
          doc_html_endnotes[segment_filename] ~= t[1];
          break;
        case 5: .. case 7:
          auto t = xhtml_format.heading_seg(obj, _txt, suffix, "seg");
          doc_html[segment_filename] ~= t[0].to!string;
          doc_html_endnotes[segment_filename] ~= t[1];
          break;
        case 8: .. case 9:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
            writeln(__FILE__, ":", __LINE__, ": ", obj.text);
          }
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
          }
          break;
        }
      } else {
        assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
        switch (obj.metainfo.is_of_part) {
        case "frontmatter":             assert(part == "head" || "toc_seg");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "toc":
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
            }
            break;
          }
          break;
        case "body":                    assert(part == "body");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "para":
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          case "block":
            switch (obj.metainfo.is_a) {
            case "quote":
              auto t = xhtml_format.quote_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "group":
              auto t = xhtml_format.group_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "block":
              auto t = xhtml_format.block_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "poem":
              break;
            case "verse":
              auto t = xhtml_format.verse_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0].to!string;
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "code":
              doc_html[segment_filename] ~= xhtml_format.code(obj, _txt);
              break;
            case "table":
              doc_html[segment_filename] ~= xhtml_format.table(obj, _txt);
              doc_html_endnotes[segment_filename] ~= "";
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
            }
            break;
          }
          break;
        case "backmatter":
          assert(part == "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "endnote":             assert(part == "endnotes");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0];
              break;
            case "glossary":            assert(part == "glossary");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0];
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "bibliography":        assert(part == "bibliography");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0];
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "bookindex":           assert(part == "bookindex_seg");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0];
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            case "blurb":               assert(part == "blurb");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "seg");
              doc_html[segment_filename] ~= t[0];
              doc_html_endnotes[segment_filename] ~= t[1];
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
            }
            break;
          }
          break;
        case "comment":
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_part);
          }
          break;
        }
      }
    }
  }
  seg_write_output(doc_matters, doc_html, doc_html_endnotes);
}
#+END_SRC

*** write output files

#+name: output_html_seg
#+BEGIN_SRC d
void seg_write_output(M,D,E)(
  M doc_matters,
  D doc_html,
  E doc_html_endnotes,
) {
  debug(asserts) {
    static assert(is(typeof(doc_html)      == string[][string]));
  }
  mixin SiSUoutputRgxInit;
  auto rgx = Rgx();
  auto pth_html = SiSUpathsHTML!()(doc_matters.output_path, doc_matters.src.language);
  auto xhtml_format = outputXHTMLs();
  auto m = doc_matters.src.filename.matchFirst(rgx.src_fn);
  try {
    if (!exists(pth_html.seg(doc_matters.src.filename))) {
      pth_html.seg(doc_matters.src.filename).mkdirRecurse;
    }
    foreach (seg_filename; doc_matters.xml.segnames) {
      auto f = File(pth_html.fn_seg(doc_matters.src.filename, seg_filename), "w");
      foreach (docseg; doc_html[seg_filename]) {
        f.writeln(docseg);
      }
      foreach (docseg; doc_html_endnotes[seg_filename]) {
        f.writeln(docseg);
      }
      f.writeln(xhtml_format.tail);
    }
  }
  catch (ErrnoException ex) {
    // handle error
  }
  writeln(" ", pth_html.fn_seg(doc_matters.src.filename, "toc"));
}
#+END_SRC

** css                                                                 :css:

#+name: output_html_css
#+BEGIN_SRC d
void css(M)(
  auto return ref M          doc_matters,
) {
  auto css = SiSUcss();
  auto pth_html = SiSUpathsHTML!()(doc_matters.output_path, doc_matters.src.language);
  try {
    if (!exists(pth_html.css)) {
      (pth_html.css).mkdirRecurse;
    }
    auto f = File(pth_html.fn_seg_css, "w");
    f.writeln(css.html_seg_css);
    f = File(pth_html.fn_scroll_css, "w");
    f.writeln(css.html_scroll_css);
  }
  catch (ErrnoException ex) {
    // Handle error
  }
}
#+END_SRC

** images                                                              :images:

#+name: copy_html_images
#+BEGIN_SRC d
void images_cp(M)(
  auto return ref M          doc_matters,
) {
  { /+ (copy html images) +/

    auto pth_html = SiSUpathsHTML!()(doc_matters.output_path, doc_matters.src.language);
    if (!exists(pth_html.image)) {
      pth_html.image.mkdirRecurse;
    }
    foreach (image; doc_matters.srcs.image_list) {
      auto fn_src_in = doc_matters.src.image_dir_path ~ "/" ~ image;
      auto fn_src_out = pth_html.image ~ "/" ~ image;
      debug(images_html) {
        writeln(fn_src_in, " -> ", fn_src_out);
      }
      if (exists(fn_src_in)) {
        fn_src_in.copy(fn_src_out);
      } else {
        writeln("WARNING image not found: ", fn_src_in);
      }
    }
  }
}
#+END_SRC

* _epub_ [#B]                                         :module:sdp:output_epub3:

|-----------------------+--------------------------+---------------------------+----------------------------------|
| function              | filename                 | module                    | variable                         |
|-----------------------+--------------------------+---------------------------+----------------------------------|
| identify doc filetype | mimetype                 | epub3_mimetypes           | mimetypes                        |
|-----------------------+--------------------------+---------------------------+----------------------------------|
| identify doc root     | META-INF/container.xml   | epub3_container_xml       | meta_inf_container_xml           |
|-----------------------+--------------------------+---------------------------+----------------------------------|
| doc manifest          | OEBPS/content.opf        | epub3_oebps_content       | oebps_content_opf                |
|-----------------------+--------------------------+---------------------------+----------------------------------|
| doc navigation        | OEBPS/toc_nav.xhtml      | epub3_oebps_toc_nav_xhtml | oebps_toc_nav_xhtml              |
|                       | OEBPS/toc.ncx            | epub2_oebps_toc_ncx       | oebps_toc_ncx                    |
|-----------------------+--------------------------+---------------------------+----------------------------------|
| doc contents          | OEBPS/[files ... ].xhtml | outputEPub3               | doc_epub3[seg_filename]          |
|                       |                          |                           | doc_epub3_endnotes[seg_filename] |
|-----------------------+--------------------------+---------------------------+----------------------------------|

** module template

#+BEGIN_SRC d :tangle ../src/sdp/output/epub3.d
module sdp.output.epub3;
template outputEPub3() {
  <<output_imports>>
  mixin InternalMarkup;
  mixin outputXHTMLs;
  <<output_epub3_fixed>>
  <<output_epub3_constructs>>
  <<output_epub3_xhtml>>
  <<output_epub3_xhtml_seg>>
  <<output_epub3_css>>
}
#+END_SRC

** special (epub) files                                             :format:
*** DONE static
**** _identify doc filetype_ (mimetype) [static]

- mimetype file indicating that zip file contains an EPUB

#+name: output_epub3_fixed
#+BEGIN_SRC d
string epub3_mimetypes() {
  string o;
  o = format(q"¶application/epub+zip¶") ~ "\n";
  return o;
}
#+END_SRC

**** _identify doc root_ (META-INF/container.xml) [static] rootfile: contains document root path

- identifies the root package document (so systems can find it), [unchanged from epub2]

#+name: output_epub3_fixed
#+BEGIN_SRC d
string epub3_container_xml() {
  string o;
  o = format(q"¶<?xml version='1.0' encoding='utf-8'?>¶") ~ "\n";
  o ~= format(q"¶<container version="1.0"
xmlns="urn:oasis:names:tc:opendocument:xmlns:container">
<rootfiles>
  <rootfile full-path="OEBPS/content.opf"
    media-type="application/oebps-package+xml" />
</rootfiles>¶") ~ "\n</container>\n";
  return o;
}
#+END_SRC

*** constructs (in dir: OEBPS)
**** TODO _doc manifest_ (OEBPS/content.opf) manifest, register content: files, images etc.

- manifest, listing all resources
- provides the default reading order
- identifies the navigation document

#+name: output_epub3_constructs
#+BEGIN_SRC d
string epub3_oebps_content(D,M,P)(D doc_abstraction, M doc_matters, P parts) {
  auto xhtml_format = outputXHTMLs();
  auto pth_epub3 = SiSUpathsEPUB!()(doc_matters.output_path, doc_matters.src.language);
  string uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO sort uuid in doc_matters!
  string content = format(q"¶  <?xml version='1.0' encoding='utf-8'?>
<package xmlns="http://www.idpf.org/2007/opf" version="2.0" unique-identifier="EPB-UUID">
  <metadata
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xmlns:dcterms="http://purl.org/dc/terms/"
    xmlns:dc="http://purl.org/dc/elements/1.1/"
    unique-identifier="urn:uuid:%s" version="2.0">
    <!-- <dc:title id="title">%s</dc:title> -->
    <dc:title id="title">%s</dc:title>
    <meta refines="#title" property="title-type">main</meta>
    <dc:title id="subtitle">%s</dc:title>
    <meta refines="#subtitle" property="title-type">subtitle</meta>
    <dc:creator file-as="%s" id="aut">%s</dc:creator>
    <dc:language>%s</dc:language>
    <dc:date id="published">%s</dc:date>
    <dc:rights>Copyright: %s</dc:rights>
    <dc:identifier scheme="URI">%s</dc:identifier>
    <dc:identifier id="bookid">urn:uuid:%s</dc:identifier>
    <!-- <dc:identifier id="EPB-UUID">urn:uuid:%s</dc:identifier> -->
  </metadata>
  <manifest>
    <!-- NCX epub2 navigation -->
      <item id="ncx" href="toc.ncx" media-type="application/x-dtbncx+xml" />
    <!-- CSS Style Sheets -->
      <link rel="stylesheet" href="%s" type="text/css" id="main-css" />
    <!-- nav epub3 navigation -->
      <item id="nav" href="toc_nav.xhtml" media-type="application/xhtml+xml" properties="nav" />
¶",
    uuid,
    xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_full),
    xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_main),
    (doc_matters.conf_make_meta.meta.title_sub.empty)
      ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_sub),
    (doc_matters.conf_make_meta.meta.creator_author.empty)
      ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.creator_author),
    (doc_matters.conf_make_meta.meta.creator_author.empty)
      ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.creator_author),
    doc_matters.src.language,                                   // language, fix (needed in dochead metadata)
    (doc_matters.conf_make_meta.meta.date_published.empty)
      ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.date_published),
    (doc_matters.conf_make_meta.meta.rights_copyright.empty)
      ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.rights_copyright),
    uuid,
    uuid,
    uuid,
    (pth_epub3.fn_oebps_css(doc_matters.src.filename)).chompPrefix("OEBPS/"),
  );
  content ~= "    " ~ "<!-- Content Documents -->" ~ "\n  ";
  content ~= parts["manifest_documents"];
  // TODO sort jpg & png
  content ~= "    " ~ "<!-- Images -->" ~ "\n  ";
  foreach (image; doc_matters.srcs.image_list) {
    content ~= format(q"¶      <item id="%s" href="%s/%s" media-type="image/%s" />
¶",
      image.baseName.stripExtension,
      (pth_epub3.doc_oebps_image(doc_matters.src.filename)).chompPrefix("OEBPS/"),
      image,
      image.extension.chompPrefix("."),
    );
  }
  content ~= "  " ~ "</manifest>"         ~ "\n  ";
  content ~= "  " ~ "<spine toc=\"ncx\">" ~ "\n  ";
  content ~= parts["spine"];
  content ~= "  " ~ "</spine>"            ~ "\n  ";
  content ~= "  " ~ "<guide>"             ~ "\n  ";
  content ~= parts["guide"];
  content ~= "  " ~ "</guide>"            ~ "\n  ";
  content ~= ""   ~ "</package>";
  debug(epubmanifest) {
    foreach (s; doc_matters.xml.keys_seq.seg) {
      foreach (obj; doc_abstraction[s]) {
        if (obj.metainfo.is_a == "heading") {
          if (obj.metainfo.heading_lev_markup == 4) {
            writefln(
              "%s~ [%s.xhtml] %s",
              obj.marked_up_level,
              obj.tags.segment_anchor_tag,
              obj.text
            );
          } else if (obj.metainfo.heading_lev_markup > 4) {
            writefln(
              "%s~ [%s.xhtml#%s] %s",
              obj.marked_up_level,
              obj.tags.segment_anchor_tag,
              obj.metainfo.object_number,
              obj.text
            );
          }
        }
      }
    }
  }
  return content;
}
#+END_SRC

**** _doc navigation epub3_ (OEBPS/toc_nav.xhtml) epub3 navigable toc using Dom structure

- toc_nav.xhtml declared as nav file in content.opf (epub3 navigation document)

#+name: output_epub3_constructs
#+BEGIN_SRC d
string epub3_oebps_toc_nav_xhtml(D,I)(D doc_abstraction, I doc_matters) {
  enum DomTags { none, open, close, close_and_open, open_still, }
  auto markup = InlineMarkup();
  auto rgx = Rgx();
  string toc =format("<html xmlns=\"http://www.w3.org/1999/xhtml\"
    xmlns:epub=\"http://www.idpf.org/2007/ops\">
<head>
  <title>%s</title>
</head>
<body>
  <section epub:type=\"frontmatter toc\">
    <header>
      <h1>Contents</h1>
    </header>
    <nav epub:type=\"toc\" id=\"toc\">\n",
    doc_matters.conf_make_meta.meta.title_full,
  );
  foreach (sect; doc_matters.xml.keys_seq.seg) {
    foreach (obj; doc_abstraction[sect]) {
      if (obj.metainfo.is_a == "heading") {
        string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
        foreach_reverse (n; 0 .. 7) {
          string k = n.to!string;
          switch (obj.metainfo.dom_collapsed[n]) {
          case DomTags.close :
            toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
            toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "</ol>" ~ "\n";
            break;
          case DomTags.close_and_open :
            toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
            if  (obj.metainfo.heading_lev_markup < 4) {
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
              ~ markup.indent_by_spaces_provided((n + 2), "  ")
              ~ "<a href=\"" ~ obj.tags.segment_anchor_tag ~ ".xhtml" ~ "\">"
              ~ _txt
              ~ "</a>" ~ "\n";
            } else {
              string hashtag =(obj.metainfo.heading_lev_markup == 4)
              ? ""
              : ("#" ~ obj.metainfo.ocn.to!string);
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
              ~ markup.indent_by_spaces_provided((n + 2), "  ")
              ~ "<a href=\"" ~ obj.tags.segment_anchor_tag ~ ".xhtml" ~ hashtag ~ "\">"
              ~ _txt
              ~ "</a>" ~ "\n";
            }
            break;
          case DomTags.open :
            toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "<ol>" ~ "\n";
            if  (obj.metainfo.heading_lev_markup < 4) {
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
              ~ markup.indent_by_spaces_provided((n + 2), "  ")
              ~ "<a href=\"" ~ obj.tags.segment_anchor_tag ~ ".xhtml" ~ "\">"
              ~ _txt
              ~ "</a>" ~ "\n";
            } else {
              string hashtag =(obj.metainfo.heading_lev_markup == 4)
              ? ""
              : ("#" ~ obj.metainfo.ocn.to!string);
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
              ~ markup.indent_by_spaces_provided((n + 2), "  ")
              ~ "<a href=\"" ~ obj.tags.segment_anchor_tag ~ ".xhtml" ~ hashtag ~ "\">"
              ~ _txt
              ~ "</a>" ~ "\n";
            }
            break;
          default :
            break;
          }
        }
      }
    }
  }
  toc ~="</nav>
    </section>
  </body>
</html>\n";
  return toc;
}
#+END_SRC

**** TODO _doc navigation epub2_ (OEBPS/toc.ncx) navigable toc using Dom structure

- toc.ncx (epub2 navigation document)
  - (replaced in epub3 by a declared xhtml nav file, in our case toc_nav.xhtml)

#+name: output_epub3_constructs
#+BEGIN_SRC d
string epub2_oebps_toc_ncx(D,I)(D doc_abstraction, I doc_matters) {
  int counter = 0;
  string uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO shared elsewhere
  auto markup = InlineMarkup();
  auto rgx = Rgx();
  enum DomTags { none, open, close, close_and_open, open_still, }
  string toc = format(q"¶<?xml version='1.0' encoding='utf-8'?>
<ncx xmlns="http://www.daisy.org/z3986/2005/ncx/" version="2005-1">
<head>
  <!-- four required metadata items (for all NCX documents,
    (including the relaxed constraints of OPS 2.0) -->
  <title>%s%s</title>
  <link rel="stylesheet" href="css/epub.css" type="text/css" id="main-css" />
  <meta name="dtb:uid" content="urn:uuid:%s" />
  <!-- <meta name="epub-creator" content="SiSU http://www.jus.uio.no/sisu (this copy)" /> -->
  <meta name="dtb:depth" content="%s" />
  <meta name="dtb:totalPageCount" content="0" />
  <meta name="dtb:maxPageNumber" content="0" />
</head>
<docTitle>
  <text>%s</text>
</docTitle>
<docAuthor>
  <text>%s</text>
</docAuthor>
<navMap>¶",
    doc_matters.conf_make_meta.meta.title_full,                          // title
    (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
      : " by " ~ doc_matters.conf_make_meta.meta.creator_author,         // author
    uuid,                                                               // uuid
    "3",                                                                // content depth
    doc_matters.conf_make_meta.meta.title_full,                          // title
    (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
      : doc_matters.conf_make_meta.meta.creator_author,                  // author
  );
  foreach (sect; doc_matters.xml.keys_seq.seg) {
    foreach (obj; doc_abstraction[sect]) {
      if (obj.metainfo.is_a == "heading") {
        string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
        string hashtag =(obj.metainfo.heading_lev_markup <= 4) ? "" : ("#" ~ obj.metainfo.ocn.to!string);
        foreach_reverse (k; 0 .. 7) {
          switch (obj.metainfo.dom_markedup[k]) {
          case DomTags.close :
            toc ~= "\n    </navPoint>";
            break;
          case DomTags.close_and_open :
            ++counter;
            toc ~= "\n    </navPoint>";
            toc ~= format(q"¶
  <navPoint class="chapter" id="navpoint" playOrder="%s">
    <navLabel>
      <text>%s</text>
    </navLabel>
    <content src="%s.xhtml%s" />¶",
              counter,
              _txt,
              obj.tags.segment_anchor_tag,
              hashtag,
            );
            break;
          case DomTags.open :
            ++counter;
            toc ~= format(q"¶
  <navPoint class="chapter" id="navpoint" playOrder="%s">
    <navLabel>
      <text>%s</text>
    </navLabel>
    <content src="%s.xhtml%s" />¶",
              counter,
              _txt,
              obj.tags.segment_anchor_tag,
              hashtag,
            );
            break;
          default :
            break;
          }
        }
      }
    }
  }
  toc ~= format(q"¶  </navMap>
</ncx>¶");
  return toc;
}
#+END_SRC

** the document contents                                               :seg:
*** ↻ loop & switch (sections & objects) format epub3 xhtml output

#+name: output_epub3_xhtml_seg
#+BEGIN_SRC d
void outputEPub3(D,I)(
  auto return ref const D    doc_abstraction,
  auto return ref I          doc_matters,
) {
  mixin SiSUoutputRgxInit;
  auto xhtml_format = outputXHTMLs();
  auto rgx = Rgx();
  string[][string] doc_epub3;
  string[][string] doc_epub3_endnotes;
  string[] doc;
  string segment_filename;
  string[] top_level_headings = ["","","",""];
  string[string] oepbs_content_parts;
  string suffix = ".xhtml";
  string[] doc_parts_;
  foreach (part; doc_matters.xml.keys_seq.seg) {
    foreach (obj; doc_abstraction[part]) {
      string _txt = xhtml_format.special_characters(obj, obj.text);
      if (obj.metainfo.is_a == "heading") {
        assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
        switch (obj.metainfo.heading_lev_markup) {
        case 0: .. case 3:
          /+ fill buffer, and replace with new levels from 1 to 3 +/
          switch (obj.metainfo.heading_lev_markup) {
          case 0:
            top_level_headings[0] = "";
            top_level_headings[1] = "";
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 1:
            top_level_headings[1] = "";
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 2:
            top_level_headings[2] = "";
            top_level_headings[3] = "";
            goto default;
          case 3:
            top_level_headings[3] = "";
            goto default;
          default:
            doc_parts_ ~= obj.tags.segment_anchor_tag;
            doc_epub3[obj.tags.segment_anchor_tag] ~= xhtml_format.epub3_seg_head(doc_matters);
            auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
            doc_epub3[obj.tags.segment_anchor_tag] ~= t[0];
            doc_epub3_endnotes[obj.tags.segment_anchor_tag] ~= t[1];
            break;
          }
          break;
        case 4:
          segment_filename = obj.tags.segment_anchor_tag;
          doc_epub3[segment_filename] ~= xhtml_format.epub3_seg_head(doc_matters);
          auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
          doc_epub3[segment_filename] ~= t[0];
          doc_epub3_endnotes[segment_filename] ~= t[1];
          break;
        case 5: .. case 7:
          auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
          doc_epub3[segment_filename] ~= t[0];
          doc_epub3_endnotes[segment_filename] ~= t[1];
          break;
        case 8: .. case 9:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
            writeln(__FILE__, ":", __LINE__, ": ", obj.text);
          }
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
          }
          break;
        }
      } else {
        assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
        switch (obj.metainfo.is_of_part) {
        case "frontmatter":             assert(part == "head" || "toc_seg");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "toc":
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
            }
            break;
          }
          break;
        case "body":                    assert(part == "body");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "para":
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          case "block":
            switch (obj.metainfo.is_a) {
            case "quote":
              auto t = xhtml_format.quote_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0].to!string;
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "group":
              auto t = xhtml_format.group_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0].to!string;
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "block":
              auto t = xhtml_format.block_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0].to!string;
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "poem":
              break;
            case "verse":
              auto t = xhtml_format.verse_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0].to!string;
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "code":
              doc_epub3[segment_filename] ~= xhtml_format.code(obj, _txt);
              break;
            case "table":
              doc_epub3[segment_filename] ~= xhtml_format.table(obj, _txt);
              doc_epub3_endnotes[segment_filename] ~= "";
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
            }
            break;
          }
          break;
        case "backmatter":
          assert(part == "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
          switch (obj.metainfo.is_of_type) {
          case "para":
            switch (obj.metainfo.is_a) {
            case "endnote":             assert(part == "endnotes");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              break;
            case "glossary":            assert(part == "glossary");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "bibliography":        assert(part == "bibliography");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "bookindex":           assert(part == "bookindex_seg");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            case "blurb":               assert(part == "blurb");
              auto t = xhtml_format.para_seg(obj, _txt, suffix, "epub");
              doc_epub3[segment_filename] ~= t[0];
              doc_epub3_endnotes[segment_filename] ~= t[1];
              break;
            default:
              if ((doc_matters.opt.action.debug_do)) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
              }
              break;
            }
            break;
          default:
            if ((doc_matters.opt.action.debug_do)) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
            }
            break;
          }
          break;
        case "comment":
          break;
        default:
          if ((doc_matters.opt.action.debug_do)) {
            writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_part);
          }
          break;
        }
      }
      if (obj.metainfo.is_a == "heading") {
        assert(obj.text.length > 0);
        if (obj.metainfo.heading_lev_markup <= 4) {
          oepbs_content_parts["manifest_documents"] ~=
            format(q"¶      <item id="%s.xhtml" href="%s.xhtml" media-type="application/xhtml+xml" />
¶",
            obj.tags.segment_anchor_tag,
            obj.tags.segment_anchor_tag,
          );
          oepbs_content_parts["spine"] ~=
            format(q"¶    <itemref idref="%s.xhtml" linear="yes" />
¶",
            obj.tags.segment_anchor_tag,
          );
          oepbs_content_parts["guide"] ~=
            format(q"¶      <reference type="%s" href="%s" />
¶",
            obj.tags.segment_anchor_tag,
            obj.tags.segment_anchor_tag,
          );
        } else if (obj.metainfo.heading_lev_markup > 4) {
          oepbs_content_parts["manifest_documents"] ~=
            format(q"¶      <item id="%s.xhtml#%s" href="%s.xhtml#%s" media-type="application/xhtml+xml" />
¶",
            obj.tags.segment_anchor_tag,
            obj.metainfo.object_number,
            obj.tags.segment_anchor_tag,
            obj.metainfo.object_number,
          );
          oepbs_content_parts["spine"] ~=
            format(q"¶    <itemref idref="%s.xhtml#%s" linear="yes" />
¶",
            obj.tags.segment_anchor_tag,
            obj.metainfo.object_number,
          );
          oepbs_content_parts["guide"] ~=
            format(q"¶      <reference type="%s#%s" href="%s#%s" />
¶",
            obj.tags.segment_anchor_tag,
            obj.metainfo.object_number,
            obj.tags.segment_anchor_tag,
            obj.metainfo.object_number,
          );
        }
      }
    }
  }
  /+ epub specific documents +/
  auto mimetypes = epub3_mimetypes;
  auto meta_inf_container_xml = epub3_container_xml;
  auto oebps_toc_ncx = epub2_oebps_toc_ncx(doc_abstraction, doc_matters);
  auto oebps_toc_nav_xhtml = epub3_oebps_toc_nav_xhtml(doc_abstraction, doc_matters);
  auto oebps_content_opf = epub3_oebps_content(doc_abstraction, doc_matters, oepbs_content_parts);
  epub3_write_output_files(
    doc_matters,
    doc_epub3,
    doc_epub3_endnotes,
    mimetypes,
    meta_inf_container_xml,
    oebps_toc_nav_xhtml,
    oebps_toc_ncx,
    oebps_content_opf,
    doc_parts_,
  );
}
#+END_SRC

** write output files

#+name: output_epub3_xhtml_seg
#+BEGIN_SRC d
void epub3_write_output_files(M,D,E,Mt,Mic,Otnx,Otn,Oc)(
  M    doc_matters,
  D    doc_epub3,
  E    doc_epub3_endnotes,
  Mt   mimetypes,
  Mic  meta_inf_container_xml,
  Otnx oebps_toc_nav_xhtml,
  Otn  oebps_toc_ncx,
  Oc   oebps_content_opf,
  string[] doc_parts_,
) {
  debug(asserts) {
    static assert(is(typeof(doc_epub3)              == string[][string]));
    static assert(is(typeof(mimetypes)              == string));
    static assert(is(typeof(meta_inf_container_xml) == string));
    static assert(is(typeof(oebps_toc_nav_xhtml)    == string));
    static assert(is(typeof(oebps_toc_ncx)          == string));
    static assert(is(typeof(oebps_content_opf)      == string));
  }
  auto pth_epub3 = SiSUpathsEPUB!()(doc_matters.output_path, doc_matters.src.language);
  auto xhtml_format = outputXHTMLs();
  /+ zip file +/
  auto fn_epub = pth_epub3.epub_file(doc_matters.src.filename);
  auto zip = new ZipArchive(); // ZipArchive zip = new ZipArchive();
  /+ zip archive member files +/
  try {
    if (!exists(pth_epub3.base)) {
      pth_epub3.base.mkdirRecurse;
    }
    debug(epub_output) {
      if (!exists(pth_epub3.dbg_doc_meta_inf(doc_matters.src.filename))) {
        pth_epub3.dbg_doc_meta_inf(doc_matters.src.filename).mkdirRecurse;
      }
      if (!exists(pth_epub3.dbg_doc_oebps_css(doc_matters.src.filename))) {
        pth_epub3.dbg_doc_oebps_css(doc_matters.src.filename).mkdirRecurse;
      }
      if (!exists(pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename))) {
        pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename).mkdirRecurse;
      }
    }
    { /+ OEBPS/[segments].xhtml (the document contents) +/
      foreach (seg_filename; doc_matters.xml.segnames_lv_0_to_4) {
        string fn = pth_epub3.fn_oebps_content_xhtml(doc_matters.src.filename, seg_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        debug(epub_output) {
          string fn_dbg = pth_epub3.dbg_fn_oebps_content_xhtml(doc_matters.src.filename, seg_filename);
          auto f = File(fn_dbg, "w");
        }
        foreach (docseg; doc_epub3[seg_filename]) {
          debug(epub_output) { f.writeln(docseg); }
          zip_data.write(docseg.dup);
        }
        foreach (docseg; doc_epub3_endnotes[seg_filename]) {
          debug(epub_output) { f.writeln(docseg); }
          zip_data.write(docseg.dup);
        }
        debug(epub_output) { f.writeln(xhtml_format.tail); }
        zip_data.write(xhtml_format.tail.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        /+ create the zip file +/
        createZipFile!()(fn_epub, zip.build());
      }
    }
    string fn;
    debug(epub_output) { string fn_dbg; }
    File f;
    { /+ mimetypes (identify zip file type) +/
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_mimetypes(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(mimetypes);
      }
      fn = pth_epub3.fn_mimetypes(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(mimetypes.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
    { /+  META-INF/container.xml (identify doc root) +/
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_dmi_container_xml(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(meta_inf_container_xml);
      }
      fn = pth_epub3.fn_dmi_container_xml(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(meta_inf_container_xml.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
    { /+ OEBPS/toc_nav.xhtml (navigation toc epub3) +/
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_oebps_toc_nav_xhtml(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(oebps_toc_nav_xhtml);
      }
      fn = pth_epub3.fn_oebps_toc_nav_xhtml(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(oebps_toc_nav_xhtml.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
    { /+ OEBPS/toc.ncx (navigation toc epub2) +/
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_oebps_toc_ncx(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(oebps_toc_ncx);
      }
      fn = pth_epub3.fn_oebps_toc_ncx(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(oebps_toc_ncx.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
    { /+ OEBPS/content.opf (doc manifest) +/
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_oebps_content_opf(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(oebps_content_opf);
      }
      fn = pth_epub3.fn_oebps_content_opf(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(oebps_content_opf.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
    { /+ OEBPS/_sisu/image (images) +/
      foreach (image; doc_matters.srcs.image_list) {
        debug(epub_output) {
          if (exists(doc_matters.src_path_info.image_root ~ "/" ~ image)) {
            (doc_matters.src_path_info.image_root ~ "/" ~ image)
            .copy((pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename)) ~ "/" ~ image);
          }
        }
      }
      foreach (image; doc_matters.srcs.image_list) {
        debug(epub_output) {
          debug(epub_images) {
            writeln(
              doc_matters.src.image_dir_path, "/", image, " -> ",
              pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename), "/", image
            );
          }
        }
        auto fn_src = doc_matters.src.image_dir_path ~ "/" ~ image;
        auto fn_out =  pth_epub3.doc_oebps_image(doc_matters.src.filename.to!string) ~ "/" ~ image;
        if (exists(fn_src)) {
          {
            auto zip_arc_member_file = new ArchiveMember();
            zip_arc_member_file.name = fn_out;
            auto zip_data = new OutBuffer();
            zip_data.write(cast(char[]) ((fn_src).read));
            zip_arc_member_file.expandedData = zip_data.toBytes();
            zip.addMember(zip_arc_member_file);
            createZipFile!()(fn_epub, zip.build());
          }
        }
      }
    }
    { /+ OEBPS/epub.css +/
      auto css = SiSUcss();
      debug(epub_output) {
        fn_dbg = pth_epub3.dbg_fn_oebps_css(doc_matters.src.filename);
        File(fn_dbg, "w").writeln(css.epub_css);
      }
      fn = pth_epub3.fn_oebps_css(doc_matters.src.filename);
      auto zip_arc_member_file = new ArchiveMember();
      zip_arc_member_file.name = fn;
      auto zip_data = new OutBuffer();
      zip_data.write(css.epub_css.dup);
      zip_arc_member_file.expandedData = zip_data.toBytes();
      zip.addMember(zip_arc_member_file);
      createZipFile!()(fn_epub, zip.build());
    }
  }
  catch (ErrnoException ex) {
    // Handle error
  }
  writeln(" ", fn_epub);
#+END_SRC

** zip debug, read zip  archive

#+name: output_epub3_xhtml_seg
#+BEGIN_SRC d
  debug(epub_archive) {
    if (exists(fn_epub)) {
      try {
        auto zipped = new ZipArchive((fn_epub).read);
        foreach (filename, member; zipped.directory) {
          auto data = zipped.expand(member);
          writeln(filename, " length ", data.length);
        }
      }
      catch (ZipException ex) {
        // Handle errors
      }
    }
  }
}
#+END_SRC

* __END__