From 2d9778dc01c8ca6c5a915e1ee638251878990d10 Mon Sep 17 00:00:00 2001
From: Ralph Amissah <ralph.amissah@gmail.com>
Date: Tue, 13 Oct 2020 14:09:43 -0400
Subject: build nix derivation (using dub2nix helper tool)

- nix-shell
- nix-build

- dub2nix (dub to nix helper tool)
  - Lionello Lunesu
  - MIT License
  - https://github.com/lionello/dub2nix
---
 mkDub.nix | 125 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 125 insertions(+)
 create mode 100644 mkDub.nix

(limited to 'mkDub.nix')

diff --git a/mkDub.nix b/mkDub.nix
new file mode 100644
index 0000000..8fe20a3
--- /dev/null
+++ b/mkDub.nix
@@ -0,0 +1,125 @@
+{ pkgs ? import <nixpkgs> {},
+  stdenv ? pkgs.stdenv,
+  rdmd ? pkgs.rdmd,
+  #dmd ? pkgs.dmd,
+  #gcc ? pkgs.gcc,
+  ldc ? pkgs.ldc,
+  dub ? pkgs.dub
+}:
+
+with stdenv;
+let
+  # Filter function to remove the .dub package folder from src
+  filterDub = name: type: let baseName = baseNameOf (toString name); in ! (
+    type == "directory" && baseName == ".dub"
+  );
+
+  # Convert a GIT rev string (tag) to a simple semver version
+  rev-to-version = builtins.replaceStrings ["v" "refs/tags/v"] ["" ""];
+
+  dep2src = dubDep: pkgs.fetchgit { inherit (dubDep.fetch) url rev sha256 fetchSubmodules; };
+
+  # Fetch a dependency (source only for now)
+  fromDub = dubDep: mkDerivation rec {
+    name = "${src.name}-${version}";
+    version = rev-to-version dubDep.fetch.rev;
+    nativeBuildInputs = [ rdmd ldc dub ];
+    src = dep2src dubDep;
+
+    buildPhase = ''
+      runHook preBuild
+      export HOME=$PWD
+      dub build -b=release
+      runHook postBuild
+    '';
+
+    # outputs = [ "lib" ];
+
+    # installPhase = ''
+    #   runHook preInstall
+    #   mkdir -p $out/bin
+    #   runHook postInstall
+    # '';
+  };
+
+  # Adds a local package directory (e.g. a git repository) to Dub
+  dub-add-local = dubDep: "dub add-local ${(fromDub dubDep).src.outPath} ${rev-to-version dubDep.fetch.rev}";
+
+  # The target output of the Dub package
+  targetOf = package: "${package.targetPath or "."}/${package.targetName or package.name}";
+
+  # Remove reference to build tools and library sources
+  disallowedReferences = deps: [ ldc rdmd dub ] ++ builtins.map dep2src deps;
+
+  removeExpr = refs: ''remove-references-to ${lib.concatMapStrings (ref: " -t ${ref}") refs}'';
+
+in {
+  inherit fromDub;
+
+  mkDubDerivation = lib.makeOverridable ({
+    src,
+    nativeBuildInputs ? [],
+    dubJSON ? src + "/dub.json",
+    selections ? src + "/dub.selections.nix",
+    deps ? import selections,
+    passthru ? {},
+    package ? lib.importJSON dubJSON,
+    ...
+  } @ attrs: stdenv.mkDerivation (attrs // {
+
+    pname = package.name;
+
+    nativeBuildInputs = [ rdmd ldc dub pkgs.removeReferencesTo ] ++ nativeBuildInputs;
+    disallowedReferences = disallowedReferences deps;
+
+    passthru = passthru // {
+      inherit dub ldc rdmd pkgs;
+    };
+
+    src = lib.cleanSourceWith {
+      filter = filterDub;
+      src = lib.cleanSource src;
+    };
+
+    preFixup = ''
+      find $out/bin -type f -exec ${removeExpr (disallowedReferences deps)} '{}' + || true
+    '';
+
+    buildPhase = ''
+      runHook preBuild
+
+      export HOME=$PWD
+      ${lib.concatMapStringsSep "\n" dub-add-local deps}
+      dub build --compiler=ldc2 --build=release --combined --skip-registry=all
+      #dub build -b optimize -b inline --combined --skip-registry=all
+
+      runHook postBuild
+    '';
+
+    checkPhase = ''
+      runHook preCheck
+
+      export HOME=$PWD
+      ${lib.concatMapStringsSep "\n" dub-add-local deps}
+      dub test --combined --skip-registry=all
+
+      runHook postCheck
+    '';
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out/bin
+      cp -r "${targetOf package}" $out/bin
+
+      runHook postInstall
+    '';
+
+    meta = lib.optionalAttrs (package ? description) {
+      description = package.description;
+    } // attrs.meta or {};
+  } // lib.optionalAttrs (!(attrs ? version)) {
+    # Use name from dub.json, unless pname and version are specified
+    name = package.name;
+  }));
+}
-- 
cgit v1.2.3