summaryrefslogtreecommitdiffhomepage
path: root/dlang/flake.nix
diff options
context:
space:
mode:
Diffstat (limited to 'dlang/flake.nix')
-rw-r--r--dlang/flake.nix63
1 files changed, 63 insertions, 0 deletions
diff --git a/dlang/flake.nix b/dlang/flake.nix
new file mode 100644
index 0000000..3aa9a60
--- /dev/null
+++ b/dlang/flake.nix
@@ -0,0 +1,63 @@
+{
+ description = "ocda-lib: the object-centric document abstraction as a D library";
+
+ inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+
+ outputs = { self, nixpkgs }:
+ let
+ system = "x86_64-linux"; # adjust for aarch64-linux / darwin
+ pkgs = import nixpkgs { inherit system; };
+
+ /* A library, so there is nothing to install as a binary. What is
+ built here are the two programs that put the library to the
+ question: the agreement check, which loads a document's .ssp and
+ its .ocda.db and compares the two models, and the dump, which
+ writes a loaded model out canonically so that an implementation in
+ another language can be diffed against this one.
+ */
+ mkTool = { tool, binary, what, compiler, compilerBin }:
+ pkgs.stdenv.mkDerivation {
+ pname = "ocda-lib-${tool}";
+ version = "2.0.0";
+ src = self;
+ nativeBuildInputs = [ compiler ];
+ buildInputs = [ pkgs.sqlite pkgs.zstd ];
+ buildPhase = ''
+ runHook preBuild
+ export HOME=$TMPDIR
+ ${compilerBin} -I=src -of=${tool} src/ocda/*.d test/${tool}.d -L-lsqlite3 -L-lzstd
+ runHook postBuild
+ '';
+ installPhase = ''
+ runHook preInstall
+ mkdir -p $out/bin
+ install -m755 ${tool} $out/bin/${binary}
+ runHook postInstall
+ '';
+ meta = {
+ description = what;
+ mainProgram = binary;
+ };
+ };
+
+ ldc = { compiler = pkgs.ldc; compilerBin = "ldmd2"; };
+ in {
+ packages.${system} = {
+ default = self.packages.${system}.ocda-agree;
+
+ ocda-agree = mkTool (ldc // {
+ tool = "agree"; binary = "ocda-agree";
+ what = "checks that the .ssp and .ocda.db loaders give one model";
+ });
+
+ ocda-dump = mkTool (ldc // {
+ tool = "dump"; binary = "ocda-dump";
+ what = "writes a loaded abstraction out canonically, as an oracle";
+ });
+ };
+
+ devShells.${system}.default = pkgs.mkShell {
+ packages = [ pkgs.ldc pkgs.dub pkgs.dtools pkgs.sqlite pkgs.zstd ];
+ };
+ };
+}